Game Skyrim Forum

Ok is there a way to make it so a race is under a blindness effect while in sunlight using the editor with no scripts.

Ive tried a new spell assign it to abilities and added sundamage to magnitude of 0 and blindness as well but they are blind all the time.....if i slaped the vampirism would that work?

Ok i think i have no choice but see if i can get someone to writeme a script that will make the player suffer a penalty while in sunlight only.....anyone feel like being generous?

I'd try something like this (not tested/going to test)

begin qweRaceOnLoadScript

; usage:
; give the race a dummy "qweRaceAbility" with any dummy effect you like
; create a "qweRaceDaylightBlindCurse" curse with blind effect
; add the script to autostarted scripts

short lastInterior
if ( GetInterior == lastInterior )
	return
endif
set lastInterior to GetInterior

if ( player->GetSpellEffects "qweRaceAbility" )
else
	stopscript qweRaceOnLoadScript
	return
endif

short state
if ( GameHour < 7 )
	set state to 0
elseif ( GameHour > 19 )
	set state to 0
else
	set state to 1
endif

if ( lastInterior )
	if ( GetWaterLevel == 0 )
		if ( GetWindSpeed > 0.01 )
			set state to ( state + 1 )
		endif
	endif
else
	set state to ( state + 1 )
endif

if ( state > 1 )
	if ( player->GetSpellEffects "qweRaceDaylightBlindCurse" )
		return
	endif
	player->AddSpell "qweRaceDaylightBlindCurse"
	return
endif

player->RemoveSpell "qweRaceDaylightBlindCurse"
player->RemoveSpellEffects "qweRaceDaylightBlindCurse"

end

Alright i hit the recompile all

and it doesnt compile the script and i get a sjitload of gmsts...what am i doing wrong?

to avoid generating GMSTs when you edit a mod in CS, try loading also Morrowind.esm, Tribunal.esm, Bloodmoon.esm as masters. And/or learn to http://wiki.theassimilationlab.com/mmw/GMST_Contamination /prevent them with GMST vaccine.

You don't need to recompile all scripts, just the new one (2nd icon, save)

or post a link to the mod containing just the race and the spells

[EDIT]also, global scripts like this one, containing a call to themselves (stopscript scriptname) need to be saved 2 times to compile correctly because the first time the CS can't find the script name as it is not saved yet

Abot

Think this is what ya asked....

I cleaned gmsts with tes5cmd

https://www.sendspace.com/file/nvhi1b

qwert

https://drive.google.com/open?id=0Bywrx4WHfGJJV2lUekJrU0tBOWc it is also cleaned from dirty scripts you generated using recompile all with not all masters loaded

Cool thanks abot....

Love ya mods.....

just started branching off with ya mods..

loved the silt riders,boats

wasnt aware of the gaurs

and trying a few other of your goodies out.....

oh yeah...thanks for making them Abot they are wonderfull.

Abot it works like a charm...

thanks so much.

there was a script archive somewhere on the web where you could upload a script and people could use it...there was a lot but no blindness script.